Лабораторная работа №35 «Язык программирования Турбо Паскаль: Про-цедуры и функции. Структура программ и модулей»

1.Цель и задачи лабораторной работы

Приобретение навыков программирования на языке Турбо Паскаль..

2.Теоретические сведения

2.1.Программы, которые не разделены на отдельные структурные элементы, называются монолитными. Большие монолитные программы сложны для разработки, отладки и сопровождения. Минимальным автономным элементом монолитной программы является оператор.

Естественно стремление разбить программу на более крупные чем операторы компоненты. Роль таких компонент выполняют процедуры и функции. Программы, состоящие из процедур и функций, называются модульными. Процедуры и функции в свою очередь могут вызывать процедуры и функции более низкого уровня и т.д. Таким образом, каждая модульная программа, имеет иерархическую структуру. Модульные программы легче для разработки и проще для понимания, чем монолитные. Рассмотрим отдельные структурные элементы модульной программы — процедуры и функции. Для процедур и функций часто используется общее название подпрограммы.

Процедурой называется часть программы, предназначенная для решения определенной задачи или подзадачи. Перед использованием процедуру необходимо объявить в разделе объявлений. Каждая процедура объявляется только однажды, а использовать ее можно многократно. Синтаксическими элементами процедуры являются: имя, список параметров и тело процедуры. Тело процедуры есть набор объявлений и последовательность операторов. Если процедура объявлена, то ее можно использовать задавая ее имя и, если необходимо, список аргументов. Операторы, использующие процедуры, называются вызовами или обращениями к процедурам. Вызов процедуры приводит к выполнению операторов, составляющих тело процедуры. После этого управление переходит к оператору, следующему за вызовом процедуры.

Рассмотрим два способа составления программы для решения одной и той же задачи. Один ориентирован на создание монолитной программы, другой — модульной. Рассмотрим программу печати документа, разделяющую главы тремя строками звездочек :

Program Ex1;                  {пример1}

       Uses WinCrt;

       Var  I, J: Integer;

       Begin

              Writeln (‘текст первой главы’);  {вывод текста первой главы}

              For J:=1 to 3 Do   Begin

                                              For I:=1 to 60 Do Write (‘*’);

                                              Writeln

                                          End;

              Writeln (‘текст второй главы’);   {вывод текста второй главы}

              For J:=1 to 3 Do

                                          Begin

                                              For I:=1 to 60 Do  Write(‘*’);

                                              Writeln

                                          End;

       End.

C другой стороны, можно оформить вывод разделителя — трех строк звездочек — в виде процедуры.

Аргументы и параметры. Для того, чтобы процедура могла выполнять аналогичные, но разные действия, необходимо снабдить ее набором параметров. В нашем случае целесообразно предусмотреть три параметра: один, определяющий длину выводимой строки символов; второй, задающий число выводимых строк, и третий, показывающий, какие именно символы будут использоваться в качестве разделителей. Тогда программа, включающая в свой состав процедуру, будет иметь вид:

Program Ex2;                    {Пример 2}

       Uses WinCrt;

       Procedure DrawStr (Len: integer; Val:Byte; Ch:Char);

              Var   I,J: Integer;

              Begin

                     For I:=1 to Val Do

                            Begin

                                   For J:=1 to Len Do  Write (Ch);

                                   Writeln

                            End

              End;

       Begin

              Writeln (‘текст первой главы’);

              DrawStr(78,3,’+’);

              Writeln (‘текст второй главы’);

              DrawStr (78,3,’+’);

       End.

Значения, стоящие в круглых скобках процедуры, называются аргументами. Реализация вызова предусматривает, в первую очередь, установление связи между аргументами и параметрами.. В данном случае все достаточно просто: параметру LEN будет присвоено значение 78, параметру VAL — значение 2, а параметру Ch значение ‘+’ типа Char. Аргумент и параметр должны относиться к совместным типам, т.е. значение аргумента должно быть таким, чтобы его можно было назначить параметру. После того, как связь между параметром и аргументом установлена, выполняются операторы, входящие в тело процедуры.

С помощью параметров можно не только передавать данные в вызываемую процедуру, т.е. осуществить прямую передачу информации, но и передавать данные из вызываемой процедуры в вызывающую. Делается это с помощью атрибута VAR. Предположим, необходимо уметь переводить температуру из шкалы по Цельсию в шкалу по Фаренгейту. Для перевода можно использовать следующую процедуру:

Procedure TransfCF (Cgrad:Real;Var FGrad:Real);

       Begin

              FGrad:=CGrad*9/5+32;

       End;

       А вызов ее осуществлять так:

       TransfCF (TempC, TempF);

Тогда в качестве значения TempF в вызывающую процедуру (или программу) будет возвращено значение температуры в градусах по Фаренгейту. Это возможно только благодаря тому, что в списке параметров для переменной Fgrad использован атрибут VAR.

Остановимся подробнее на работе механизма аргументов-параметров. Существует два метода передачи данных с помощью этого механизма: передача по значению и передача по адресу (или по имени). В случае передачи по значению аргумент просто посылается в стек. Если же передача осуществляется по адресу, то в стек передается адрес той области памяти, где хранится значение аргумента. Таким образом, в последнем случае для параметра отводится та же самая область памяти, что и для аргумента, т.е. все изменения, происходящие с параметром, будут происходить и с аргументом. Наличие у параметра атрибута VAR свидетельствует о том, что используется передача по адресу. Следовательно, если параметр имеет атрибут VAR, то соответствующий аргумент должен быть переменной , а не константой или выражением.

При определении типов параметров можно использовать либо простые стандартные, либо ранее объявленные типы. Другими словами, тип параметра обязательно должен определяться единственным идентификатором. Например, недопустим такой заголовок процедуры

Procedure A(B:Array [1…2] of Byte; Const C: String [20] );

Правильным является следующий фрагмент :

Type       Barr: Array [1…2] of Byte;

              Cstr: String [20];

Procedure A(B:Barr; Const C:Cstr);

Области действия имен. Под именами будем понимать имена констант, переменных, типов, процедур и функций, а также меток. Имена могут быть объявлены в главной программе, процедурах или функциях, а также в модулях. Имена, объявленные в главной программе, называются глобальными. К ним возможен доступ из любой процедуры или функции. Имена, объявленные в процедуре или функции, называются локальными. Доступ к ним возможен только из тела той подпрограммы, в которой они описаны. Областью действия локального имени является та подпрограмма, по отношению к которой объявление является внутренним, плюс все содержащиеся в ней подпрограммы. Рассмотрим структуру программы с областями действия имен:

Функция отличается от процедуры тем, что возвращает в точку вызова одно скалярное значение. В принципе объявление функции похоже на объявление процедуры. Дополнительно при описании функции необходимо задавать тип возвращаемого значения, а в теле функции присваивать имени функции значение. Это присваивание осуществляется точно так же, как и присваивание значения обычной переменной. Например,

       Function Fgrad (Cgrad: Real): Real;

              Begin

                     FGrad:=CGrad*9/5+32;

              End;

Вызов функции принципиально отличается от вызова процедуры. Для вызова функции достаточно использовать ее имя в выражении. Вызов функции может появляться там, где разрешено использовать значение, тип которого совпадает с типом значения, возвращаемого функцией. Функцию Fgrad можно вызывать, например, так:

FAR:=FGrad (CEL);

Процедурный тип. Ранее уже были введены все простые (скалярные) типы данных: INTEGER, REAL, BYTE, WORD, SHORTINT, LONGINT, CHAR, BOOLEAN и структурированные типы: интервальный, перечисляемый, регулярный, комбинированный и множественный. Все они описывают данные, а не процессы.

В отличие от этих типов рассмотрим новый тип данных, который называется процедурным. Наличие процедурного типа дает возможность использовать процедуры и функции в качестве параметров. В качестве элементов процедурного типа могут выступать как процедуры, так и функции. Например,

       Type

              Proc1=Procedure (Var A:Integer; B:Byte);

              Func1=Function (S:Real):Real;

Элементами процедурного типа Proc1 являются любые процедуры с двумя параметрами INTEGER и BYTE. Можно также сказать, что элементами типа Proc1 будут процедуры, заголовки которых тождественны заголовку, присутствующему в описании этого типа. Аналогично, элементами процедурного типа Func1 будут любые функции с единственным параметром типа REAL, возвращающие значение типа REAL.

Например, для проведения численного интегрирования можно использовать одну общую для всех функций процедуру интегрирования:

Program Ex3;          {пример 3}

              Uses WinCrt;

              Type

                     Func1=Function (S:Real):Real;

              Var

                     M, N:Integer;

                     L,R,SQV:Real;

              {$F+}

              Function Sin1(X:Real):Real;

                     Begin

                            Sin1:=Sin(X);

              End;

              Function Trf (X:Real):Real;

                     Begin

                            Trf:=Cos(X)*Cos(X)+1;

                     End;

              {$F-}

              Function Simple(LB,RB:Real; N: Integer; F: Func1):Real;

              {LB и RB — левая и правая границы интегрирования}

                     Var

                            I:Integer;

                            Step, Int: Real;

                     Begin

                            Step:=(RB-LB)/N;

                            Int:=0;

                            For I:=1 to N Do

                                   Int:=Int+F(LB+(I-0.5)*Step)*Step;

                            Simple:=Int;

                     End;

              Begin       {главная программа}

                     Writeln (‘ Введите номер функции: 1 для sin(x)’,#13#10,

                                                                               2  для cos(x)*cos(x)+1′);

                     Readln (M);

                     Writeln (‘введите значения границ интегрирования’);

                     Readln (L,R);

                     Writeln (‘введите число точек разбиения’);

                     Readln (N);

                     Case M of

                            1: SQV:=Simple (L,R,N,sin1);

                            2: SQV:=Simple (L,R,N,Trf);

                     end;

                     Writeln (‘результат интегрирования=’,SQV);

              End.

2.2.Структура программ и модулей. Программа состоит из главной программы  и возможно нескольких модулей. Тексты главной программы и модулей размещаются в различных файлах. Выполнение всегда начинается с главной программы; операционная система осуществляет вызов того файла с расширением .ЕХЕ, который содержит код главной программы.

Модуль — это программная единица, допускающая автономную компиляцию. Выполнение модуля может инициироваться главной программой или другими модулями. Делается это с помощью вызова процедуры или функции, входящей в состав модуля. Использование модулей дает возможность нескольким программистам заниматься разработкой одной программы, облегчая отладку и сопровождение программного обеспечения.

Главная программа по своей структуре напоминает процедуру. Правда, в отличие от процедуры заголовок для программы, хотя и желателен, но не обязателен. Заголовок главной программы имеет вид

Program <имя>;

USES <список имен модулей>;

Далее расположена декларативная часть главной программы, включающая объявления типов, констант, переменных, меток, процедур и функций. Порядок следования этих объявлений не существенен. Важно, чтобы используемые для текущего объявления элементы уже были определены. Например:

       Const

              P=5;

       Type

              Q=Array [1…P] of Real;

В этом фрагменте константа Р может быть использована для формирования типа Q только после ее объявления. Объявление вначале типа Q, а затем константы Р привело бы к ошибке.

За декларативной частью главной программы следует исполняемая часть. Она начинается ключевым словом BEGIN и заканчивается ключевым словом END. После END обязательно должна стоять точка. Между BEGIN и END располагаются операторы языка Турбо Паскаль. Объявлений в исполняемой части главной программы быть не должно.

Структура модуля. В его состав могут входить несколько процедур и функций. Модули предназначены для выделения из текста программ процедур и функций с целью их автономной отладки и компиляции, т.е. создания библиотек подпрограмм. Чтобы использовать подпрограмму из модуля, надо в программе с помощью оператора USES объявить имя модуля, содержащего эту подпрограмму.

Структура модуля напоминает структуру программы, хотя налицо существенные различия.

                                   Unit <имя>;

Секция                                     Interface

связи                                               Uses <список-1 имен модулей>;

                                                        <внешние объявления>;

Секция                              Implementation

реализации               Uses <список-2 имен модулей>;

                                                       <внутренние объявления>;

Секция                               Begin

инициализации                <последовательность операторов>;

                                           End.

Модуль обязательно начинается с ключевого слова UNIT, за которым следует идентификатор — имя модуля. Для того, чтобы гарантировать правильную работу модуля в системе программирования Турбо Паскаль, необходимо поместить исходный текст этого модуля в файл с расширением PAS, имя которого совпадает с именем модуля. Другими словами, если заголовок модуля имеет вид

UNIT Mod1;

Завершается модуль, так же, как и главная программа, ключевым словом END с точкой.

Имя модуля служит для организации связи модуля с главной программой и другими модулями. Связь между модулями устанавливается с помощью оператора USES. Секция связи начинается с оператора USES, следом за которым должны размещаться так называемые внешние объявления. Внешние объявления описывают элементы, которые считаются известными за пределами модуля. К ним относятся объявления типов, констант, переменных и подпрограмм. При объявлении подпрограмм, т.е. процедур и функций, в секции связи указываются только их заголовки. Полные тексты процедур и функций, заголовки которых находятся в секциях связи, размещаются  в секции реализации. Ниже приведен пример секции связи :

       Unit Mod2;

       Interface

              Const

                     MaxL=100;

              Type

                     Intl=1..MaxL;

              Var

                     Width:Real;

                     Flag:Boolean;

              Procedure SQR1(A:Int1;Var B: Integer);

              Function STR1(S:String):Boolean;

Предположим теперь, что в главной программе или каком-то модуле присутствует оператор

USES MOD2;

Тогда для главной программы или модуля доступными окажутся константа MAXL, тип INT1, переменные WIDTH и FLAG, процедура SQR1 и функция STR1.

Секция реализации начинается с ключевого слова IMPLEMENTATION и обязательно включает полные тексты подпрограмм, описанных в секции связи. Но перед телами этих подпрограмм может стоять оператор USES и располагаться набор внутренних объявлений модуля. Как обычно, в операторе USES указываются имена модулей. Внешние объявления этих модулей доступны в секции реализации: во-первых, они могут участвовать в формировании внутренних объявлений модуля и, во-вторых, могут использоваться при описании процедур и функций. В секции реализации в области внутренних объявлений можно описывать константы, типы, переменные, процедуры и функции. Эти объекты считаются известными во всех подпрограммах секции реализации. Но внутренние объявления являются локальными, т.е. действуют только внутри того модуля, в котором они размещаются. Однако эти недоступные извне элементы могут использоваться “глобальными” процедурами и функциями, заголовки которых присутствуют в секции связи. Заголовок подпрограммы в секции реализации должен либо полностью совпадать с заголовком этой же подпрограммы в секции связи, либо содержать только имя подпрограммы. Следующий пример показывает, как может выглядеть секция реализации модуля, секция связи которого взята из предыдущего примера.

       IMPLEMENTATION

              Const

                     Five=5;

              Procedure SQR1;

                     Const

                     B1=Five+6;

                     Begin

                            B:=B1*A;

                     End;

              Function STR1;

                     Var

                            C:Int1;

                     Begin

              Readln (C);

                            If Length(S)<C Then

                                                 STR1:=True

                                                    Else

                                   STR1:=False

                     End;

Заключительной секцией модуля, которая впрочем чаще всего отсутствует, является секция инициализации. Она начинается с ключевого слова BEGIN. Далее обычно следует последовательность исполняемых операторов. Секции инициализации всех модулей, входящих в программу, выполняются один раз перед началом работы главной программы. Они используются для подготовки главной программы и модулей к началу работы и могут включать операторы, осуществляющие присваивание начальных значений переменным, дополнительные проверки паролей пользователей и т.п. В секции инициализации известными считаются внешние объявления секции связи, внутренние объявления секции реализации и внешние объявления всех модулей, имена которых присутствуют в операторах USES этого модуля.

Организация связей между программными модулями. В операторе USES главной программы не обязательно указывать имена всех используемых программой модулей. Дело в том, что некоторые модули могут не вызываться непосредственно из главной программы: к ним могут быть обращения из других модулей. Вообще программа имеет четко выраженную иерархическую структуру. Более точно структура программы, компонентами которой являются модули, представляет собой сеть без циклов. Как известно, вершины ациклической сети могут быть упорядочены и распределены по уровням. Например,

Отметим, что недопустимы прямые и косвенные обращения модулей к самим себе.

В качестве примера использования модулей рассмотрим следующую программу, представляющую собой модификацию Примера 3:

Program Ex4;          {пример 4}

       Uses WinCrt, Funcex;

       Var

              M, N:Integer;

              L,R,SQV:Real;

       Begin

              Writeln (‘ Введите номер функции: 1 для sin(x)’,#13#10,

                                                                        2 для cos(x)*cos(x)+1′);

              Readln (M);

              Writeln (‘введите значения границ интегрирования’);

                  Readln (L,R);

              Writeln (‘введите число точек разбиения’);

              Readln (N);

              Case M of

                     1: SQV:=Simple (L,R,N,sin1);

                     2: SQV:=Simple (L,R,N,Trf);

              end;

              Writeln (‘результат интегрирования=’,SQV);

       End.

Unit funcex;

interface

Type

              Func1=Function (S:Real):Real;

Function Sin1(X:Real):Real;

       Function Trf (X:Real):Real;

       Function Simple(LB,RB:Real; N: Integer; F: Func1):Real;

implementation

       Function Sin1(X:Real):Real;

              Begin

                     Sin1:=Sin(X);

              End;

       Function Trf (X:Real):Real;

              Begin

                            Trf:=Cos(X)*Cos(X)+1;

              End;

       Function Simple(LB,RB:Real; N: Integer; F: Func1):Real;

       {LB и RB — левая и правая границы интегрирования}

              Var

                     I:Integer;

                     Step, Int: Real;

              Begin

                     Step:=(RB-LB)/N;

                     Int:=0;

                     For I:=1 to N Do

                            Int:=Int+F(LB+(I-0.5)*Step)*Step;

                     Simple:=Int;

       End;

end.

3.Оборудование для лабораторной работы

4.Порядок выполнения работы

1. Прочитать п.2 настоящего руководства и выполнить предписанные в нем действия.
2. Закрепить полученные знания, ответив на вопросы для самотестирования.

©2008-2020, Интернет-институт ТулГУ